What You Need to Know About Data Classifications in Azure SQL Data Warehouse

Data classifications in Azure SQL DW entered public preview in March 2019. They allow you to label columns in your data warehouse with their information type and sensitivity level. There are built-in classifications, but you can also add custom classifications. This could be an important feature for auditing your storage and use of sensitive data as well as compliance with data regulations such as GDPR. You can export a report of all labeled columns, and you can see who is querying sensitive columns in your audit logs. The Azure Portal will even recommend classifications based upon your column names and data types. You can add the recommended classifications with a simple click of a button.

You can add data classifications in the Azure Portal or via T-SQL or PowerShell. Data classifications are database objects.

ADD SENSITIVITY CLASSIFICATION TO
    dbo.DimCustomer.Phone
    WITH (LABEL='Confidential', INFORMATION_TYPE='Contact Info')

To view existing data classifications, you can query the sys.sensitivity_classifications view or look in the Azure Portal.

SELECT
sys.all_objects.name as [TableName], 
sys.all_columns.name as [ColumnName],
[Label], 
[Information_Type], 
FROM sys.sensitivity_classifications
left join sys.all_objects on sys.sensitivity_classifications.major_id = sys.all_objects.object_id
left join sys.all_columns on sys.sensitivity_classifications.major_id = sys.all_columns.object_id
    and sys.sensitivity_classifications.minor_id = sys.all_columns.column_id

Be Careful When Loading With CTAS and Rename

One issue that is specific to using data classifications in Azure SQL DW is that it is possible to inadvertantly drop your classifications when you are loading your tables using the recommended T-SQL load pattern. Typically, when using T-SQL to load a dimensional model in Azure SQL DW, we perform the following steps:

1. Create an upsert table via CTAS with the results of a union of new data from a staging table with existing data from the dimension table
2. Rename the dimension table to something like Dimension_OLD
3. Rename the upsert table to Dimension
4. Drop the Dimension_OLD table

In the animation above, you’ll first see the load process as described, and then it will replay with sensitivity labels added to the dimension table. You’ll see that they are dropped when we drop the old dimension table. This makes sense because sensitivity classifications are objects related to that table. We would expect an index to be dropped when we drop the related table. This works the same way.

Check out my SQL notebook for a demonstration of the issue as well as my workaround that I describe below. If you spin up an Azure SQL Data Warehouse with the sample database, you can run this notebook from Azure Data Studio and see the results for yourself.

There are a few complicating factors:

• There are currently no visual indicators of sensitivity classifications in SSMS or Azure Data Studio.
• ETL developers may not have access to the data warehouse in the Azure Portal to see the sensitivity classifications there.
• The entire process of adding and managing sensitivity classifications may be invisible to an ETL developer. A data modeler or business analyst might be the person adding and managing the sensitivity classifications. If the ETL developer isn’t aware classifications have been added, they won’t know to go and look for them in the sys.sensitivity_classifications view.
• SSDT does not yet support sensitivity classifications. The only way I have found to add them into the database project is as a post-deployment script with the build property set to none.

The good news is that you can add the sensitivity classifications back to your dimension table using T-SQL. The bad news is still that the ETL developer must remember to do it. My workaround for now is a stored procedure that will do the the rename and drop of the tables plus copy the sensitivity classifications over. My hope is that it it’s easier to remember to use it since it will do the rename and drop for you as well.

Update: Someone asked about the name SwapWithMetadata and why it doesn’t specifically mention sensitivity classifications. I didn’t mention classifications because there are other things that need this same treatment. Dynamic data masking will also need to be reapplied. With dynamic data masking, it will be even more important to add it back immediately after swapping the tables rather than waiting for a full data load of all selected tables to finish and adding all classifications back. If your load takes a long time or the process fails on another table, you don’t want your data exposed without a mask to users who shouldn’t see the full information.

	CREATE PROC SwapWithMetadata
	@SrcSchema NVARCHAR(128),
	@SrcTable NVARCHAR(128),
	@DestSchema NVARCHAR(128),
	@DestTable NVARCHAR(128),
	@TransferMetadata BIT,
	@DropOldTable BIT
	AS
	BEGIN
	SET NOCOUNT ON
	BEGIN TRY
	–Check if destination table exists
	DECLARE @DestSchemaQualifiedTableName NVARCHAR(257)
	SET @DestSchemaQualifiedTableName = @DestSchema + '.' + @DestTable
	IF OBJECT_ID(@DestSchemaQualifiedTableName) IS NULL
	BEGIN
	DECLARE @DestErr NVARCHAR(MAX)
	SET @DestErr = 'Table ' + @DestSchemaQualifiedTableName + ' not found'
	RAISERROR(@DestErr, 15, 1)
	END
	–Check if source table exists
	DECLARE @SrcSchemaQualifiedTableName NVARCHAR(257)
	SET @SrcSchemaQualifiedTableName = @SrcSchema + '.' + @SrcTable
	IF OBJECT_ID(@SrcSchemaQualifiedTableName) IS NULL
	BEGIN
	DECLARE @SrcErr NVARCHAR(MAX)
	SET @SrcErr = 'Table ' + @SrcSchemaQualifiedTableName + ' not found'
	RAISERROR(@SrcErr, 15, 1)
	END
	–Move destination table to destination_old. Move source table to destination
	DECLARE @RenameSql NVARCHAR(MAX)
	SET @RenameSql = 'RENAME OBJECT ' + @DestSchemaQualifiedTableName + ' TO ' + @DestTable + '_old; '
	Set @RenameSql = @RenameSql + ' RENAME OBJECT ' + @SrcSchemaQualifiedTableName + ' TO ' + @DestTable
	PRINT 'Executing ' + @RenameSql + ' …'
	EXEC sp_executesql @RenameSql;
	–drop temp table if it exists
	IF OBJECT_ID('tempDB..#tempApplySensitivityClassificationsToTable') IS NOT NULL
	DROP TABLE #tempApplySensitivityClassificationsToTable;
	–check if we should transfer data classifications from old to new table
	IF ISNULL(@TransferMetadata,0) = 1
	BEGIN
	–put current classifications in a temp table
	DECLARE @OldTable NVARCHAR(128) = @DestTable + '_old';
	WITH CurrentClassifications as (
	SELECT
	CAST('dbo' as NVARCHAR(128)) [Schema],
	CAST(sys.all_objects.name as NVARCHAR(128)) [Table],
	CAST(sys.all_columns.name as NVARCHAR(128)) [Column],
	CAST([Information_Type] as NVARCHAR(128)) [Informationtype],
	CAST([Label] as NVARCHAR(128)) [Label]
	FROM
	sys.sensitivity_classifications
	LEFT OUTER JOIN sys.all_objects on sys.sensitivity_classifications.major_id = sys.all_objects.object_id
	LEFT OUTER JOIN sys.all_columns on sys.sensitivity_classifications.major_id = sys.all_columns.object_id
	and sys.sensitivity_classifications.minor_id = sys.all_columns.column_id
	)
	SELECT ROW_NUMBER() OVER (ORDER BY [Schema], [Table], [Column]) [ID],
	[Schema], [Table], [Column], [Informationtype], [Label]
	INTO #tempApplySensitivityClassificationsToTable
	FROM CurrentClassifications
	WHERE [Schema] = @DestSchema AND [Table] = @OldTable;
	DECLARE @i INT
	SET @i = 1
	DECLARE @Max INT
	SELECT @Max = COUNT(*)
	FROM #tempApplySensitivityClassificationsToTable;
	PRINT 'Transferring ' + CAST(@Max as VARCHAR(4)) + ' classifications'
	–drop and recreate sensitivity classifications
	DECLARE @Sql NVARCHAR(MAX)
	DECLARE @Col NVARCHAR(128)
	DECLARE @InfoType NVARCHAR(128)
	DECLARE @Label NVARCHAR(128)
	WHILE @i <= @Max
	BEGIN
	SELECT @Col = [Column], @InfoType = [InformationType], @Label = [Label]
	FROM #tempApplySensitivityClassificationsToTable
	WHERE Id = @i
	SET @Sql = 'DROP SENSITIVITY CLASSIFICATION FROM ' + @DestSchemaQualifiedTableName + '.' + @Col
	PRINT 'Executing ' + @Sql + '…'
	EXEC sp_executesql @Sql
	SET @Sql = 'ADD SENSITIVITY CLASSIFICATION TO ' + @DestSchemaQualifiedTableName + '.' + @Col
	IF (@InfoType IS NOT NULL AND @Label IS NOT NULL)
	BEGIN
	SET @Sql = @Sql + ' WITH (LABEL=''' + @Label + ''', INFORMATION_TYPE=''' + @InfoType + ''')'
	END
	ELSE IF (@InfoType IS NOT NULL)
	BEGIN
	SET @Sql = @Sql + ' WITH (INFORMATION_TYPE=''' + @InfoType + ''')'
	END
	ELSE IF (@Label IS NOT NULL)
	BEGIN
	SET @Sql = @Sql + ' WITH (LABEL=''' + @InfoType + ''')'
	END
	ELSE
	BEGIN
	SET @Sql = NULL
	END
	IF (@Sql IS NOT NULL)
	BEGIN
	PRINT 'Executing ' + @Sql + '…'
	EXEC sp_executesql @Sql
	END
	SET @i = @i + 1
	END
	END
	IF ISNULL(@DropOldTable,0) = 1
	BEGIN
	DECLARE @DropSql NVARCHAR(MAX)
	SET @DropSql = 'DROP TABLE ' + @DestSchemaQualifiedTableName + '_old;'
	PRINT 'Executing ' + @DropSql + '…'
	EXEC sp_executesql @DropSql;
	END
	END TRY
	BEGIN CATCH
	Print 'ERROR… Procedure: ' + ERROR_PROCEDURE() + ' Message: ' + ERROR_MESSAGE()
	END CATCH
	END

view raw SQLDWTableSwapWithClassifications hosted with ❤ by GitHub

Eventually, the tools will be updated to provide more visibility to data sensitivity classifications, but we still need to make sure they don’t get dropped.

For now, my recommendation is if you are going to go in and add a lot of sensitivity classifications, that you create a user defined restore point immediately after so that you know you have them in a backup somewhere. Azure SQL DW doesn’t do point-in-time restores the way Azure SQL DB does. It takes automatic restore points every 8 hours or so. So if someone went through the trouble of adding the sensitivity classifications and they were dropped through the data load process, there is no guarantee that you could use a backup to get them back.

Vote for My Enhancement Idea

If you would like Microsoft to add something to the product to keep sensitivity classifications from being dropped, or at least make it easier to add them back, please vote for my idea.

Not an Issue with Other Data Load Methods

Please note that if you are using other tools or methods to load your tables where you don’t swap them out, you won’t have the issue of dropping your sensitivity classifications. But I wanted to bring up this issue because I can see people spending a lot of time adding them and then suddenly losing them, and I want everyone to avoid that frustration.

Give Data Classifications a Try

I think data classifications are a good addition to SQL DW. Anything that helps us efficiently catalog and manage our sensitive data is good. I have added them in my demo environment and hope to use them in a client environment soon.

Have you tried out data classifications in SQL DW or DB? What do you think so far? If not, what is keeping you from using them?